EmguCV学习笔记 VB.Net 8.1 漫水填充法 floodFill
版权声明：本文为博主原创文章，转载请在显著位置标明本文出处以及作者网名，未经作者允许不得用于商业目的。
EmguCV是一个基于OpenCV的开源免费的跨平台计算机视觉库,它向C#和VB.NET开发者提供了OpenCV库的大部分功能。
教程VB.net版本请访问：EmguCV学习笔记 VB.Net 目录-CSDN博客
教程C#版本请访问：EmguCV学习笔记 C# 目录-CSDN博客
笔者的博客网址：https://blog.csdn.net/uruseibest
教程配套文件及相关说明以及如何获得pdf教程和代码，请移步：EmguCV学习笔记
学习VB.Net知识，请移步： vb.net 教程 目录_vb中如何用datagridview-CSDN博客
学习C#知识，请移步：C# 教程 目录_c#教程目录-CSDN博客
8.1 漫水填充法 floodFill
FloodFill方法是一种图像处理算法，它的目的是将一个闭合的区域内的像素全部涂上同一个颜色。在实现中，通常会使用递归或队列来处理待处理列表。具体的实现方式会根据具体应用场景的需求而有所不同。
CvInvoke.FloodFill方法用于执行图像的漫水填充操作，它将连通区域中的所有像素点填充为指定颜色的操作。该方法声明如下：
Public Shared Function FloodFill (
src As IInputOutputArray,
mask As IInputOutputArray,
seedPoint As Point,
newVal As MCvScalar,
<OutAttribute> ByRef rect As Rectangle,
loDiff As MCvScalar,
upDiff As MCvScalar,
Optional connectivity As Connectivity = Connectivity.FourConnected,
Optional flags As FloodFillType = FloodFillType.Default
) As Integer
参数说明：
- src：输入输出的图像，必须是单通道灰度图像或三通道彩色图像。
- mask：掩码图像，必须是单通道8位图像，并且高宽各比源图像大2。如果指定了掩码，则只有掩码中像素值为255的区域才会被填充或者标记。如果不指定掩码，则默认填充或者标记整个图像。
- seedPoint：表示种子点的坐标，即从哪个像素点开始填充或者标记连通区域。
- newVal：填充的新颜色，可以是一个标量值（单通道图像）或一个包含三个通道值的MCvScalar结构体（三通道图像）。
- rect：输出参数，表示被填充区域的边界矩形。
- loDiff：低阈值向量。如果相邻像素点的值与种子点的差值小于低阈值向量，则将其归为同一连通区域。
- upDiff：高阈值向量。如果相邻像素点的值与种子点的差值大于高阈值向量，则将其归为不同的连通区域。
- connectivity：连接性，指定像素的相邻关系。默认为八连通。
- flags：漫水填充算法的标志位。默认为FixedRange，表示使用固定的阈值范围进行填充。
返回值：
返回一个整数值，表示填充的像素个数。
【代码位置：frmChapter8】Button1_Click
'漫水填充法 floodFill
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim m As New Mat("C:\learnEmgucv\tower.jpg", ImreadModes.Color)
'种子点的坐标
Dim seedPoint As New Point(100, 100)
'填充颜色
Dim newVal As New MCvScalar(0, 255, 255)
'掩码图像
Dim mmask As New Mat
mmask = Mat.Zeros(m.Rows + 2, m.Cols + 2, DepthType.Cv8U, 1)
Dim rect As New Rectangle
' 执行漫水填充
Dim numFilledPixels As Integer = CvInvoke.FloodFill(m, mmask, seedPoint, newVal, rect,
New MCvScalar(10, 10, 10),
New MCvScalar(20, 20, 20))
'输出填充的像素个数
Console.WriteLine("Number of filled pixels: " & numFilledPixels)
'显示填充后的图像
ImageBox1.Image = m
End Sub
输出结果如下图所示：
图8-1漫水填充法实现图像分割
【代码位置：frmChapter8】Button2_Click
'漫水填充法 floodFill
'选取不同的起始点坐标进行填充
Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
Dim msrc As New Mat("c:\learnEmgucv\tower.jpg", ImreadModes.AnyColor)
ImageBox1.Image = msrc
Dim mask As New Mat(msrc.Rows + 2, msrc.Cols + 2, DepthType.Cv8U, 1)
Dim area As Integer
'从坐标(250, 250)进行填充
Dim mdst1 As Mat = msrc.Clone
area = CvInvoke.FloodFill(mdst1, mask,
New Point(250, 250),
New MCvScalar(0, 0, 255),
New Rectangle(),
New MCvScalar(40, 40, 40),
New MCvScalar(40, 40, 40),
Connectivity.FourConnected,
FloodFillType.FixedRange)
CvInvoke.Imshow("mdst1", mdst1)
'从坐标(400, 400)进行填充
Dim mdst2 As Mat = msrc.Clone
area = CvInvoke.FloodFill(mdst2, mask,
New Point(400, 400),
New MCvScalar(0, 255, 0),
New Rectangle(),
New MCvScalar(60, 60, 60),
New MCvScalar(80, 80, 80),
Connectivity.FourConnected,
FloodFillType.FixedRange)
CvInvoke.Imshow("mdst2", mdst2)
End Sub
输出结果如下图所示：
图8-2 不同坐标点填充效果
【代码位置：frmChapter8】Button3_Click
'FloodFill随机坐标点使用随机颜色填充
Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
Dim msrc As New Mat("c:\learnEmgucv\tower.jpg", ImreadModes.AnyColor)
ImageBox1.Image = msrc
Dim mask As New Mat(msrc.Rows + 2, msrc.Cols + 2, DepthType.Cv8U, 1)
Dim lodiff As New MCvScalar(20, 20, 20)
Dim hidiff As New MCvScalar(20, 20, 20)
Dim r As New Random
For i As Integer = 0 To 99
Dim x As Integer = r.Next(msrc.Cols)
Dim y As Integer = r.Next(msrc.Rows)
Dim p As New Point(x, y)
Dim newsc As New MCvScalar(r.Next(256), r.Next(256), r.Next(256))
Dim area As Integer
area = CvInvoke.FloodFill(msrc, mask,
p,
newsc,
New Rectangle(),
lodiff,
hidiff,
Connectivity.FourConnected,
FloodFillType.FixedRange)
Next
CvInvoke.Imshow("mout", msrc)
End Sub
输出结果如下图所示：
图8-3 随机坐标点使用随机颜色填充