当前位置：首页 > article >正文

ws2812b效果研究之八 pride2015

article 2025/2/22 16:35:48

这个代码实现了一个名为"Pride2015"的LED动画效果，主要是通过FastLED库生成不断变化的彩虹效果

/// @file    Pride2015.ino
/// @brief   Animated, ever-changing rainbows.
/// @example Pride2015.ino

#include "FastLED.h"

// Pride2015
// Animated, ever-changing rainbows.
// by Mark Kriegsman

#if FASTLED_VERSION < 3001000
#error "Requires FastLED 3.1 or later; check github for latest code."
#endif

#define DATA_PIN    2
//#define CLK_PIN   4
#define LED_TYPE    WS2812B
#define COLOR_ORDER GRB
#define NUM_LEDS    100
#define BRIGHTNESS  255

CRGB leds[NUM_LEDS];


void setup() {
  delay(3000); // 3 second delay for recovery
  
  // tell FastLED about the LED strip configuration
  FastLED.addLeds<LED_TYPE,DATA_PIN,COLOR_ORDER>(leds, NUM_LEDS)
    .setCorrection(TypicalLEDStrip)
    .setDither(BRIGHTNESS < 255);

  // set master brightness control
  FastLED.setBrightness(BRIGHTNESS);
}


void loop()
{
  pride();
  FastLED.show();  
}


// This function draws rainbows with an ever-changing,
// widely-varying set of parameters.
void pride() 
{
  static uint16_t sPseudotime = 0;
  static uint16_t sLastMillis = 0;
  static uint16_t sHue16 = 0;
 
  uint8_t sat8 = beatsin88( 87, 220, 250);
  uint8_t brightdepth = beatsin88( 341, 96, 224);
  uint16_t brightnessthetainc16 = beatsin88( 203, (25 * 256), (40 * 256));
  uint8_t msmultiplier = beatsin88(147, 23, 60);

  uint16_t hue16 = sHue16;//gHue * 256;
  uint16_t hueinc16 = beatsin88(113, 1, 3000);
  
  uint16_t ms = millis();
  uint16_t deltams = ms - sLastMillis ;
  sLastMillis  = ms;
  sPseudotime += deltams * msmultiplier;
  sHue16 += deltams * beatsin88( 400, 5,9);
  uint16_t brightnesstheta16 = sPseudotime;
  
  for( uint16_t i = 0 ; i < NUM_LEDS; i++) {
    hue16 += hueinc16;
    uint8_t hue8 = hue16 / 256;

    brightnesstheta16  += brightnessthetainc16;
    uint16_t b16 = sin16( brightnesstheta16  ) + 32768;

    uint16_t bri16 = (uint32_t)((uint32_t)b16 * (uint32_t)b16) / 65536;
    uint8_t bri8 = (uint32_t)(((uint32_t)bri16) * brightdepth) / 65536;
    bri8 += (255 - brightdepth);
    
    CRGB newcolor = CHSV( hue8, sat8, bri8);
    
    uint16_t pixelnumber = i;
    pixelnumber = (NUM_LEDS-1) - pixelnumber;
    
    nblend( leds[pixelnumber], newcolor, 64);
  }
}

动画逻辑分析

状态变量的初始化和更新

sPseudotime、sLastMillis、sHue16是静态变量，用于存储动画状态，使得每次调用pride函数时，这些变量的值能够保留和更新。
ms = millis()：获取当前时间（毫秒）。
deltams = ms - sLastMillis：计算自上次更新以来的时间差。
sPseudotime、sHue16根据时间差deltams进行更新，控制颜色和亮度的变化。

颜色和亮度的动态生成

sat8：饱和度，通过beatsin88函数进行动态调整，使彩虹色饱和度在220到250之间变化。
brightdepth：亮度深度，同样通过beatsin88函数，使亮度深度在96到224之间变化。
brightnessthetainc16：亮度角度增量，用于控制亮度的渐变速度。
hueinc16：颜色渐变的速度，通过beatsin88函数控制，使颜色变化更加丰富。
hue8：将hue16缩小至8位（0-255），用于生成HSV颜色。
像素亮度计算

通过sin16计算brightnesstheta16的正弦值b16，然后计算亮度bri16和bri8，以生成渐变的亮度效果。
newcolor = CHSV(hue8, sat8, bri8)：使用HSV颜色模型生成新颜色newcolor。