当前位置：首页 > article >正文

JZ2440开发板——S3C2440的时钟体系

article 2024/9/23 18:24:49

参考博客

（1）S3C2440-裸机篇-05 | S3C2440时钟体系详解（FCLK、PCLK、HCLK）

一、三种时钟（FCLK、HCLK、PCLK）

如下图所示，S3C2440的时钟控制逻辑，给整个芯片提供三种时钟：

（1）FCLK：用于CPU核；

（2）HCLK：用于接在AHB总线上的设备，比如LCD控制器、存储器控制器、中断控制器、USB主机模块等；

（3）PCLK：用于接在APB总线上的设备，比如看门狗、IIS、I2C、ADC、UART等。

另外由数据手册可知（如下图所示），CPU最大的工作频率可达400MHz，高速设备最大的工作频率可达136MHz，低速设备最大的工作频率是68MHz。

二、如何产生三种时钟

由底板原理图可知（如下图所示），时钟源是12MHz的晶振。

如何由12MHz提高到400MHz？这需要使用到 PLL（锁相环）。

我们来看一下时钟产生框图：

由图可知有两个时钟源：一个是晶振提供时钟源，另一个是通过外部引脚提供时钟源。具体选择哪个时钟源，由选择器的OM[3:2]来决定，如下图所示：

由于 OM[3:2] 引脚接地，所以其值为00，则选择晶振作为时钟源，如下所示：

由图可知，S3C2440有两个PLL，分别叫做MPLL（main PLL）、UPLL（usb PLL）。UPLL专用于USB设备，MPLL用于设置FCLK、HCLK、PCLK。它们的设置方法类似，这里以MPLL为例。

上电时，MPLL没被启动，FCLK等于外部输入的时钟（一般是晶振产生的12Mhz时钟），我们称之为Fin。如果要提高系统的时钟，需要使用软件来启用MPLL。其上电时序图如下所示：

（1）LOCKTIME 寄存器：用于设置锁相时间

Fin进入MPLL后，需要经过一定的时长（时长可以通过 LOCKTIME 寄存器进行设置，我们一般使用默认值0xFFFF-FFFF就好），MPLL才能输出倍频后的 FCLK。

（2）MPLLCON 寄存器：用于设置FCLK与Fin的倍数关系

已知给 MPLL 输入的 Fin=12MHz，如果想让MPLL输出的 FCLK = 400MHz（因为CPU最大的工作频率可达400MHz），该如何设置呢？可以通过 MPLLCON 寄存器进行设置。

有如下公式：

从MPLL输出的FCLK = (2*m*Fin)/(p*2^s)
    
    m = MDIV（即 MPLLCON[19:12] 的值 ）+ 8
    p = PDIV（即 MPLLCON[9:4] 的值 ）+ 2
    s = SDIV（即 MPLLCON[1:0] 的值 ）

数据手册会给出FCLK典型值的设置推荐值，如下图所示，我们编程时使用这些推荐值即可（虽然也可以由公式自己推算）。

（3）CLKDIVN寄存器：用于设置FCLK、HCLK、PCLK的比例

上面已经得到FCLK，那如何由它进一步得到HCLK、PCLK呢？可以将FCLK进行分频，得到HCLK、PCLK，这意味着FCLK、HCLK、PCLK三者存在比例关系。具体的分频系数，可以通过CLKDIVN寄存器进行设置，比如通过 CLKDIVN[2:1] 设置将FCLK分频多少以得到HCLK。

过程总结如下图所示：

三、编程实践

3.1 编程前的分析

在编程之前，注意数据手册有下面的一段描述：

它表明，如果HDIVN的值不设为0（为0则表示HCLK=FCLK/1，而HCLK一般不等于FCLK，所以一般不会设置为0的），则需要添加上图红框内的代码（注意将“R1_nF…”这个宏转换为实际值）。

假设我们需要设置FCLK=400MHz，HCLK=100MHz，PCLK=50MHz。

则根据第二节的描述，我们需要设置MPLLCON寄存器、CLKDIVN寄存器：

（1）关于MPLLCON寄存器的设置。由于400MHz是典型值，我们使用数据手册给出的设置：

MDIV（即 MPLLCON[19:12] 的值）：设置为92（0x5c）

PDIV（即 MPLLCON[9:4] 的值）：设置为1

SDIV（即 MPLLCON[1:0] 的值）：设置为1

那么MPLLCON寄存器的值应该设置为：(92<<12)|(1<<4)|(1<<0)

（2）关于CLKDIVN寄存器的设置。

由于 HCLK(100MHz) = FCLK(400MHz) / 4，所以CLKDIVN[2:1] = 0b10；而且CAMDIVN[9]要设置为0（初始值默认也为0，那么设不设置好像都行）。

由于 PCLK(50MHz) = HCLK(100MHz) / 2，所以CLKDIVN[0] = 1;

综合起来，CLKDIVN寄存器要设置为0b101=0x5。

3.2 编程实践

完整的代码见链接（课程提供的代码）：

（1）其中start.S文件内容如下（我仿写的）：

.text
.global _start

_start:
	
	//关看门狗
	ldr r0,=0x53000000
	ldr r1,=0
	str r1,[r0]

/*******************************************/	
	//设置HDIV、PDIV的分频系数，使得FCLK : HCLK : PCLK=400:100:50
	//通过寄存器CLKDIVN来设置分频系数
	ldr r0,=0x4c000014
	ldr r1,=0x5
	str r1,[r0]
	
	//设置CPU工作于异步模式
	mrc p15,0,r0,c1,c0,0
	orr r0,r0,#0xc0000000 //R1_nF:OR:R1_iA的值为0xc0000000
	mcr p15,0,r0,c1,c0,0
	
	//设置MPLL的锁相时间
	/* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
	ldr r0, =0x4C000000
	ldr r1, =0xFFFFFFFF
	str r1, [r0]
	
	//设置MPLL，使它输出400MHz
	ldr r0,=0x4c000004
	ldr r1,=(92<<12)|(1<<4)|(1<<0)
	str r1,[r0]
/******************************************************/

	//设置栈
	/*判断nor/nand启动方式，并设置相应的栈
	 *如何判断启动方式：写0到0地址，然后再读出来，
	 *如果得到0，则表示地址0的内容被修改了，它对应着sram，意味着nand启动
	 *否则为nor启动（因为nor不能直接写）
	 */
	//ldr r0,[0]  //读出原来的值进行备份
	mov r1,#0
	ldr r0,[r1]
	str r1,[r1] //将0写到0地址
	ldr r2,[r1] //将0地址的内容读出来
	cmp r1,r2   // r1==r2? 如果相等则表示是nand启动
	ldr sp,=0x4000000+0x1000 //先假设是nor启动（nor启动时，内部的SRAM映射到0x40000000，4096=0x1000）
	moveq sp,#4096 //如果相等则表示nand启动，将sp指向内部SRAM的最高地址处
	streq r0,[r1]  //如果相等则表示nand启动，恢复原来的值
	
	bl main

halt:
	b halt

（2）led.c文件的内容如下（我仿写的）：

#include "s3c2440_soc.h"

void delay(volatile int d)
{
	while (d--);
}

int main(void)
{
	//设置GPFCON让GPF4/5/6配置为输出引脚
	GPFCON &= ~((3<<8)|(3<<10)|(3<<12));//先清零
	GPFCON |= ((1<<8)|(1<<10)|(1<<12));//置位，设置为输出引脚
	
	GPFDAT=0xff;//全部熄灭
	//循环点亮
	while(1)
	{
		GPFDAT=0xff;//全部熄灭
		GPFDAT=0xef;//让LED1亮
		delay(100000);
		GPFDAT=0xff;//让LED1灭
	
		GPFDAT=0xdf;//让LED2亮
		delay(100000);
		GPFDAT=0xff;//让LED2灭
	
		GPFDAT=0xbf;//让LED4亮
		delay(100000);
	}
	return 0;
}

//课程的版本
#if 0

int main(void)
{
	int val = 0;  /* val: 0b000, 0b111 */
	int tmp;

	/* 设置GPFCON让GPF4/5/6配置为输出引脚 */
	GPFCON &= ~((3<<8) | (3<<10) | (3<<12));
	GPFCON |=  ((1<<8) | (1<<10) | (1<<12));

	/* 循环点亮 */
	while (1)
	{
		tmp = ~val;
		tmp &= 7;
		GPFDAT &= ~(7<<4);
		GPFDAT |= (tmp<<4);
		delay(100000);
		val++;
		if (val == 8)
			val =0;
	}
	return 0;
}

#endif

代码依据是数据手册与原理图中的相关内容，如下所示：

由下面的原理图可知，GPF4~GPF6引脚输出低电平时，对应的LED1、LED2、LED4会亮。

3.3 现象与分析

1、在课程提供的代码（见上面提到的链接）目录下执行make时，在进行链接时报错：

xjh@ubuntu:~/iot/embedded_basic/jz2440/armBareMachine/clk$ make
arm-linux-gcc -c -o led.o led.c
arm-linux-gcc -c -o start.o start.S
arm-linux-ld -Ttext 0 led.o start.o -o led.elf
led.o:(.ARM.exidx+0x0): undefined reference to `__aeabi_unwind_cpp_pr0'
led.o:(.ARM.exidx+0x8): undefined reference to `__aeabi_unwind_cpp_pr1'
make: *** [all] Error 1
xjh@ubuntu:~/iot/embedded_basic/jz2440/armBareMachine/clk$

解决方法是在 arm-linux-gcc 命令加上 -nostdlib 这个选项。它表示不链接系统标准启动文件和标准库文件，只把指定的文件传递给连接器。这个选项常用于编译内核、bootloader等程序，它们不需要启动文件、标准库文件（书P35）。

回顾一下朱的裸机课程，如果 arm-linux-ld 时只有一个待连接的.o文件，Makefile中的arm-linux-gcc命令不需要加上 -nostdlib 这个选项（比如chapter4->8.leds.s），如果有两个待链接的.o文件，则需要加上该选项（比如chapter5->3.set_sp_s及以后的裸机程序）。

这里韦的课程为何不加呢？估计与我环境不一样？

2、一些编程注意事项

（1） &=，这两个符号不能有空格，即不能写成“& =”

GPFCON & = ~((3<<8)|(3<<10)|(3<<12)); //会报错

（2）Makefile文件中arm-linux-ld时，.o文件第一个必须是start.o文件！否则可以连接成功，但烧写到开发板后没有现象。

（3）直接写成 ldr r0,[0] 貌似会报错，要写成：

mov r1,#0
ldr r0,[r1]

（4）课程的led.c文件用的是位操作，我没有仔细分析其代码，而是直接赋值修改。有时间分析一下其代码。

3、烧写现象

以NorFlash启动，在uboot的shell界面下按“n”，使用“usb下载线+dnw”方式将生成的led.bin烧写到NandFlash中。然后改为NandFlash启动，可以看见三颗LED灯在快速地循环点亮。

如果将start.S文件中两条“/**************/”之间的内容（也就是时钟初始化部分）删掉，重新编译烧写运行，可以看见三颗LED灯依然在循环点亮，但速度明显慢许多！（此时FCLK应该是12MHz，而HCLK与PCLK又是多少呢？）

四、总结

1、深入讲解了S3C2440芯片的结构

掌握了S3C2440的时钟体系架构和上电复位时序，其时钟源有两个：外部晶振或者外部时钟，通过OM[3:2]硬件选择；其内部主要调整频率的PLL有两个：MPLL（产生FCLK）和UPLL（产生UCLK）；其主要的时钟频率有三个（FCLK->CPU使用，HCLK->AHB总线高速外设使用，PCLK->APB总线低速外设使用），其中HCLK和PCLK由FCLK分频而来。

2、学习了如何进行芯片操作

掌握了如何编程设置寄存器控制S3C2440的时钟频率，比如本节设置FCLK=400Mhz，HCLK=100Mhz，PCLK=50Mhz。

3、其他一些启发

可以关闭某些模块的时钟，以达到省电的目的。比如设置CLKCON寄存器来关闭某些模块。