当前位置： 首页 > article >正文

STM32启动文件分析

article 2024/12/25 14:49:56

1. 启动文件简介

启动文件由汇编编写，是系统上电复位后第一个执行的程序。主要做了以下工作：

  • 初始化堆栈指针SP=_initial_sp;
  • 初始化程序计数器指针PC=Reset_Handler;
  • 设置堆、栈的大小;
  • 初始化中断向量表;
  • 配置外部SRAM作为数据存储器（这个由用户配置，一般的开发板可没有外部SRAM）;
  • 调用SystemIni() 函数配置STM32的系统时钟。
  • 设置C库的分支入口“__main”（最终用来调用main函数）;


2. 查找ARM汇编指令
在讲解启动代码的时候，会涉及到ARM的汇编指令和Cortex内核的指令，有关Cortex内核的指令我们可以参考《CM3权威指南CnR2》第四章：指令集。 剩下的ARM的汇编指令我们可以在MDK->Help->Uvision Help中搜索到，以EQU为例，检索如下：

检索出来的结果会有很多，我们只需要看Assembler User Guide 这部分即可。下面列出了启动文件中使用到的ARM汇编指令， 该列表的指令全部从ARM Development Tools这个帮助文档里面检索而来。其中编译器相关的指令WEAK和ALIGN为了方便也放在同一个表格了。


 

3. 启动文件代码讲解
3.1. Stack—栈
Stack_Size      EQU     0x00000400
                AREA    STACK, NOINIT, READWRITE, ALIGN=3

Stack_Mem       SPACE   Stack_Size

__initial_sp


开辟栈的大小为0X00000400（1KB，单位为字节数，这里是十六进制表示，换算成二进制是2^10字节），名字为STACK，NOINIT即不初始化，可读可写，8（2^3）字节对齐。
栈的作用是用于局部变量，函数调用，函数形参等的开销，栈的大小不能超过内部SRAM的大小。如果编写的程序比较大， 定义的局部变量很多，那么就需要修改栈的大小。如果某一天，你写的程序出现了莫名奇怪的错误，并进入了硬fault的时候，这时你就要考虑下是不是栈不够大，溢出了。
EQU：宏定义的伪指令，相当于等于，类似与C中的#define。
AREA：告诉汇编器汇编一个新的代码段或者数据段。STACK表示段名，这个可以任意命名；NOINIT表示不初始化； READWRITE表示可读可写，ALIGN=3，表示按照2^3对齐，即8字节对齐。
SPACE：用于分配一定大小的内存空间，单位为字节。这里指定大小等于Stack_Size。
标号__initial_sp紧挨着SPACE语句放置，表示栈的结束地址，即栈顶地址，栈是由高向低生长的。

3.2. Heap堆
Heap_Size     EQU     0x00000200
            AREA    HEAP, NOINIT, READWRITE, ALIGN=3

__heap_base

Heap_Mem      SPACE   Heap_Size

__heap_limit


PRESERVE8
THUMB
开辟堆的大小为0X00000200（512字节，单位为字节数，这里是十六进制表示），名字为HEAP，NOINIT即不初始化，可读可写，8（2^3）字节对齐。
__heap_base表示堆的起始地址， __heap_limit表示堆的结束地址。堆是由低向高生长的，跟栈的生长方向相反。
堆主要用来动态内存的分配，像malloc()函数申请的内存就在堆上面。这个在STM32里面用的比较少。
PRESERVE8：指定当前文件的堆栈按照8字节对齐。
THUMB：表示后面指令兼容THUMB指令。THUBM是ARM以前的指令集，16bit，现在Cortex-M系列的都使用THUMB-2指令集， THUMB-2是32位的，兼容16位和32位的指令，是THUMB的超集。

3.3. 向量表
AREA    RESET, DATA, READONLY

EXPORT  __Vectors

EXPORT  __Vectors_End

EXPORT  __Vectors_Size


定义一个数据段，名字为RESET，可读。 并声明 __Vectors、__Vectors_End和__Vectors_Size这三个标号具有全局属性，可供外部的文件调用。
EXPORT：声明一个标号可被外部的文件使用，使标号具有全局属性。如果是arm编译器，则使用的是.global这个指令。
当内核响应了一个发生的异常后，对应的异常服务例程(ESR)就会执行。为了决定 异常服务例程(ESR)的入口地址， 内核使用了“向量表查表机制”。 这里使用一张向量表，向量表其实是一个 WORD（ 32 位整数）数组，每个下标对应一种异常，该下标元素的值则是该异常服务例程(ESR)的入口地址。 向量表在地址空间中的位置是可以设置的，通过 NVIC 中的一个重定位寄存器来指出向量表的地址。在复位后，该寄存器的值为 0。因此， 在地址 0 （即FLASH 地址0）处必须包含一张向量表，用于初始时的异常分配。要注意的是这里有个另类： 0 号类型并不是什么入口地址， 而是给出了复位后 MSP 的初值。
代码清单:启动文件-1 向量表

__Vectors  DCD   __initial_sp        ;栈顶地址
        DCD   Reset_Handler       ;复位程序地址
        DCD   NMI_Handler
        DCD   HardFault_Handler
        DCD   MemManage_Handler
        DCD   BusFault_Handler
        DCD   UsageFault_Handler
        DCD   0                    ; 0 表示保留
        DCD   0
        DCD   0
        DCD   0
        DCD   SVC_Handler
        DCD   DebugMon_Handler
        DCD   0
        DCD   PendSV_Handler
        DCD   SysTick_Handler
;
;外部中断开始
        DCD   WWDG_IRQHandler
        DCD   PVD_IRQHandler
        DCD   TAMPER_IRQHandler
;
;限于篇幅，中间代码省略
        DCD   DMA2_Channel2_IRQHandler
        DCD   DMA2_Channel3_IRQHandler
        DCD   DMA2_Channel4_5_IRQHandler
__Vectors_End
__Vectors_Size EQU __Vectors_End - __Vectors

__Vectors为向量表起始地址，__Vectors_End 为向量表结束地址，两个相减即可算出向量表大小。
向量表从FLASH的0地址开始放置，以4个字节为一个单位，地址0存放的是栈顶地址，0X04存放的是复位程序的地址，以此类推。 
从代码上看，向量表中存放的都是中断服务函数的函数名，可我们知道C语言中的函数名就是一个地址。
DCD：分配一个或者多个以字为单位的内存，以四字节对齐，并要求初始化这些内存。在向量表中，DCD分配了一堆内存，并且以ESR的入口地址初始化它们。

3.4. 复位程序
AREA |.text|, CODE, READONLY
定义一个名称为.text的代码段，可读。

;Reset_Handler
Reset_Handler PROC 
            EXPORT  Reset_Handler    [WEAK]
            IMPORT  SystemInit
            IMPORT  __main
            LDR     R0, =SystemInit 
            BLX     R0 
            LDR     R0, =__main
            BX      R0
            ENDP


开头的是程序注释，在汇编里面注释用的是“;”，相当于 C 语言的“//”注释符
第二行是定义了一个子程序：Reset_Handler。PROC 是子程序定义伪指令。这里就相当于C语言里定义了一个函数，函数名为Reset_Handler。
第三行 EXPORT 表示 Reset_Handler 这个子程序可供其他模块调用。相当于C语言中声明全局函数，global意思。关键字[WEAK] 表示弱定义， 如果编译器发现在别处定义了同名的函数，则在链接时用别处的地址进行链接，如果其它地方没有定义，编译器也不报错，以此处地址进行链接。
第四行和第五行 IMPORT 表示 SystemInit 和__main 这两个标号在其他文件，在链接的时候需要到其他文件去寻找。 相当于C语言中extern，从其它文件引入函数声明。以便下面对外部函数进行调用。
SystemInit 需要由我们自己实现，即我们要编写一个具有该名称的函数，用来初始化 STM32 芯片的时钟，一般包括初始化AHB、APB等各总线的时钟， 需要经过一系列的配置STM32才能达到稳定运行的状态。这个函数在固件库里面有提供，官方已经为我们写好。
__main 其实不是我们定义的(不要与C语言中的main函数混淆)，这是一个C库函数，当编译器编译时，只要遇到这个标号就会定义这个函数， 该函数的主要功能是：负责初始化栈、堆，配置系统环境，并在函数的最后调用用户编写的 main 函数，从此来到 C 的世界。
第六行把 SystemInit 的地址加载到寄存器 R0。
第七行程序跳转到 R0 中的地址执行程序，即执行SystemInit函数的内容。
第八行把__main 的地址加载到寄存器 R0。
第九行程序跳转到 R0 中的地址执行程序，即执行__main函数，执行完毕之后就去到我们熟知的 C 世界，进入main函数。
第十行表示子程序的结束。
总之，看完这段代码后，了解到如下内容即可：我们需要在外部定义一个SystemInit函数设置STM32的时钟；STM32上电后，会执行SystemInit函数，最后执行我们C语言中的main函数。


复位子程序是系统上电后第一个执行的程序，调用SystemInit函数初始化系统时钟，然后调用C库函数_mian，最终调用main函数去到C的世界。
WEAK：表示弱定义，如果外部文件优先定义了该标号则首先引用该标号，如果外部文件没有声明也不会出错。 这里表示复位子程序可以由用户在其他文件重新实现，这里并不是唯一的。
IMPORT：表示该标号来自外部文件，跟C语言中的EXTERN关键字类似。这里表示SystemInit和__main这两个函数均来自外部的文件。
SystemInit()是一个标准的库函数，在system_stm32f10x.c这个库文件总定义。主要作用是配置系统时钟，这里调用这个函数之后，单片机的系统时钟配被配置为72M。
__main是一个标准的C库函数，主要作用是初始化用户堆栈，并在函数的最后调用main函数去到C的世界。这就是为什么我们写的程序都有一个main函数的原因。
LDR、BLX、BX是CM4内核的指令，可在《CM3权威指南CnR2》第四章-指令集里面查询到，具体作用见下表：



3.5. 中断服务程序
在启动文件里面已经帮我们写好所有中断的中断服务函数，跟我们平时写的中断服务函数不一样的就是这些函数都是空的， 真正的中断复服务程序需要我们在外部的C文件里面重新实现，这里只是提前占了一个位置而已。
如果我们在使用某个外设的时候，开启了某个中断，但是又忘记编写配套的中断服务程序或者函数名写错，那当中断来临的时， 程序就会跳转到启动文件预先写好的空的中断服务程序中，并且在这个空函数中无线循环，即程序就死在这里。

NMI_Handler     PROC    ;系统异常
                EXPORT  NMI_Handler           [WEAK]
                B       .
                ENDP


;限于篇幅，中间代码省略
SysTick_Handler PROC
                EXPORT  SysTick_Handler       [WEAK]
                B       . 
                ENDP


Default_Handler PROC    ;外部中断
                EXPORT  WWDG_IRQHandler       [WEAK]
                EXPORT  PVD_IRQHandler        [WEAK]
                EXPORT  TAMP_STAMP_IRQHandler [WEAK]

;限于篇幅，中间代码省略
LTDC_IRQHandler
LTDC_ER_IRQHandler
DMA2D_IRQHandler
                B       .
                ENDP

B：跳转到一个标号。这里跳转到一个‘.’，即表示无线循环。

3.6. 用户堆栈初始化

;用户栈和堆初始化,由C库函数_main来完成
IF      :DEF:__MICROLIB  ;这个宏在KEIL里面开启

EXPORT  __initial_sp
EXPORT  __heap_base
EXPORT  __heap_limit

ELSE

IMPORT  __use_two_region_memory ;  //相当于C语言中extern，从其它文件引入函数声明.这个函数由用户自己实现  
EXPORT  __user_initial_stackheap    //相当于声明全局函数，子程序可以被其他模块调用

__user_initial_stackheap

LDR     R0, =  Heap_Mem
LDR     R1, =(Stack_Mem + Stack_Size)
LDR     R2, = (Heap_Mem +  Heap_Size)
LDR     R3, = Stack_Mem
BX      LR

ALIGN

ENDIF

首先判断是否定义了__MICROLIB ，如果定义了这个宏则赋予标号__initial_sp（栈顶地址）、 __heap_base（堆起始地址）、__heap_limit（堆结束地址）全局属性，可供外部文件调用。 有关这个宏我们在KEIL里面配置，具体见图使用微库。然后堆栈的初始化就由C库函数_main来完成。

ALIGN：对指令或者数据存放的地址进行对齐，后面会跟一个立即数。缺省表示4字节对齐。代码如下：


如果没有定义__MICROLIB，则插入标号__use_two_region_memory，这个函数需要用户自己实现， 具体要实现成什么样，可在KEIL的帮助文档里面查询到。

然后声明标号__user_initial_stackheap具有全局属性，可供外部文件调用，并实现这个标号的内容。
IF,ELSE,ENDIF：汇编的条件分支语句，跟C语言的if ,else类似
END：文件结束
 


http://www.kler.cn/a/383058.html

相关文章：

  • Linux的mmap
  • 突发！！！GitLab停止为中国大陆、港澳地区提供服务，60天内需迁移账号否则将被删除
  • 010 Qt_输入类控件(LineEdit、TextEdit、ComboBox、SpinBox、DateTimeEdit、Dial、Slider)
  • 某集团GIF动态验证码识别
  • Oracle 数据库函数的用法（一）
  • Qwen文章阅读笔记
  • Axure是什么软件？全方位解读助力设计入门
  • 实践是认识的来源
  • GPU的内存是什么？
  • 继承——面向对象编程的基石
  • 【C++】lambda表达式的理解与运用（C++11新特性）
  • [C++ 核心编程]笔记 4.4.2 类做友元
  • 【Vue 2.x】之指令详解
  • Nat Med 病理AI系列｜人工智能在肝病临床试验中的应用·顶刊精析·24-11-06
  • QT开发：掌握现代UI动画技术：深入解析QML和Qt Quick中的动画效果
  • 用PyQt 5 开发的雷达基数据可视化软件
  • 关于c指针的一些说明
  • 第2篇 使用Intel FPGA Monitor Program创建基于ARM处理器的汇编或C语言工程＜二＞
  • 【5.10】指针算法-快慢指针将有序链表转二叉搜索树
  • Java项目实战II基于Spring Boot的问卷调查系统的设计与实现（开发文档+数据库+源码）
  • Linux 文件基本属性
  • SQL Server 日志记录
  • linux arm板启动时间同步服务
  • 数组和指针的复杂关系
  • 上尚优选项目
  • 【LeetCode】【算法】406. 根据身高重建队列