Hive分区表添加字段

分区表新增字段

hive提供了为分区表添加字段的功能，新添加的字段会处于现有列的末尾。相关语法如下：

ALTER TABLE table_name 
  [PARTITION partition_spec]                 -- (Note: Hive 0.14.0 and later)
  ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...)
  [CASCADE|RESTRICT]                         -- (Note: Hive 1.1.0 and later)

结论

1.不添加cascade只会修改表元数据
此时历史分区的新增字段均会显示NULL(无论数据是否带有新字段数据)，此时有两种解决方法

• 方式一：手动给历史分区新增字段
• 方式二：先删除历史分区再重入该历史分区数据(相比正常直接重入历史分区数据而言)

2.添加cascade会修改表和所有历史分区元数据
此时历史分区的旧数据会显示NULL，但新插入的带有新增字段的数据会正常显示

注意：如果是有多个分区字段且分区数量特别多的表，要谨慎使用cascade修改，可能造成元数据部分表锁表。

不使用cascade修改

1、准备表和数据
create table add_test(id int,name string) partitioned by (pt string) stored as parquet;
insert into table add_test partition (pt="2024-11-01") values (1,"zhangsan"),(2,"lisi");
insert into table add_test partition (pt="2024-11-02") values (3,"wangwu"),(4,"wuliu");

2、查看表和数据
desc add_test;
select id,name,pt from add_test;

3、增加字段
alter table add_test add columns(age int);

如果不添加CASCADE 此时只会修改表元数据 分区元数据没有改变

4、查看表和分区
desc add_test;
desc add_test partition (pt="2024-11-01")

5. 验证分区数据
# 插入新分区数据和历史分区数据
insert into table add_test partition (pt="2024-11-03") values (5,"a",11),(6,"b",12);
insert into table add_test partition (pt="2024-11-01") values (0,"c",21);

此时新分区数据可以正常显示新增字段信息，历史分区新增字段为NULL

6. 手动添加分区字段
alter table add_test partition (pt="2024-11-01") add columns(age int);

方式一：单独给历史分区添加字段元数据后，新增字段正常显示

7. 删除分区重入数据
alter table add_test drop partition (pt="2024-11-02");

方式二：删除分区 重新导入数据，新增字段正常显示

使用cascade修改

1、准备表和数据
create table add_test4(id int,name string) partitioned by (pt string) stored as parquet;
insert into table add_test4 partition (pt="2024-11-01") values (1,"zhangsan"),(2,"lisi");
insert into table add_test4 partition (pt="2024-11-02") values (3,"wangwu"),(4,"wuliu");

2.cascade修改
alter table add_test4 add columns(age int) cascade;

3.查看分区和表
desc add_test4;
desc add_test4 partition (pt="2024-11-01")

添加cascade后，表和分区的元数据均会更新

4.验证分区数据
insert into table add_test4 partition (pt="2024-11-01") values (0,"c",21);

此时插入历史分区的数据，也会正常显示新增字段