当前位置：首页 > article >正文

为解决局域网IP、DNS切换的Windows BAT脚本

article 2025/3/6 17:36:47

一、背景

为解决公司普通人员需要切换IP、DNS的情况，于是搞了个windows下的bat脚本，可以对有线网络、无线网络进行切换设置。

脚本内容

@echo off
title 多网络接口IP切换工具

:menu
cls
echo ============================
echo 请选择要配置的网络接口:
echo ============================
echo 1. 有线网络（以太网）
echo 2. 无线网络（Wi-Fi）
echo 3. 刷新DNS缓存
echo 4. 退出
echo ============================
set /p choice=请输入选项(1-3): 

if %choice%==1 goto wiredMenu
if %choice%==2 goto wirelessMenu
if %choice%==3 goto flushDns
if %choice%==4 goto end

:wiredMenu
cls
echo ============================
echo 选择有线网络的IP配置:
echo ============================
echo 1. 使用DHCP自动获取所有设置
echo 2. 使用DHCP自动获取IP地址 (固定DNS)
echo 3. IP配置 1 (192.168.66.101)
echo 4. IP配置 2 (192.168.1.101)
echo 5. 返回主菜单
echo ============================
set /p wiredChoice=请输入选项(1-5): 

if %wiredChoice%==1 goto wiredDhcp
if %wiredChoice%==2 goto wiredDhcpFixedDns
if %wiredChoice%==3 goto wiredIp1
if %wiredChoice%==4 goto wiredIp2
if %wiredChoice%==5 goto menu

:wiredDhcp
echo 正在设置有线网络使用DHCP自动获取IP地址和DNS...
call :applyDhcp "以太网"
goto checkConfigEthernet

:wiredDhcpFixedDns
echo 正在设置有线网络使用DHCP自动获取IP地址，但使用固定DNS...
call :applyDhcpWithFixedDns "以太网" "202.101.202.68" "202.101.224.69"
goto checkConfigEthernet

:wiredIp1
echo 应用有线网络IP配置 1...
call :applyIp "以太网" "192.168.66.101" "255.255.255.0" "192.168.66.1" "202.101.202.68" "202.101.224.69"
goto checkConfigEthernet

:wiredIp2
echo 应用有线网络IP配置 2...
call :applyIp "以太网" "192.168.1.101" "255.255.255.0" "192.168.1.1" "202.101.202.68" "202.101.224.69"
goto checkConfigEthernet

:wirelessMenu
cls
echo ============================
echo 选择无线网络的IP配置:
echo ============================
echo 1. 使用DHCP自动获取所有设置
echo 2. 使用DHCP自动获取IP地址 (固定DNS)
echo 3. IP配置 1 (192.168.1.102)
echo 4. IP配置 2 (192.168.1.103)
echo 5. 返回主菜单
echo ============================
set /p wirelessChoice=请输入选项(1-5): 

if %wirelessChoice%==1 goto wirelessDhcp
if %wirelessChoice%==2 goto wirelessDhcpFixedDns
if %wirelessChoice%==3 goto wirelessIp1
if %wirelessChoice%==4 goto wirelessIp2
if %wirelessChoice%==5 goto menu

:wirelessDhcp
echo 正在设置无线网络使用DHCP自动获取IP地址和DNS...
call :applyDhcp "WLAN"
goto checkConfigWifi

:wirelessDhcpFixedDns
echo 正在设置无线网络使用DHCP自动获取IP地址，但使用固定DNS...
call :applyDhcpWithFixedDns "WLAN" "202.101.202.68" "202.101.224.69"
goto checkConfigWifi

:wirelessIp1
echo 应用无线网络IP配置 1...
call :applyIp "WLAN" "192.168.1.102" "255.255.255.0" "192.168.1.1" "202.101.202.68" "202.101.224.69"
goto checkConfigWifi

:wirelessIp2
echo 应用无线网络IP配置 2...
call :applyIp "WLAN" "192.168.1.103" "255.255.255.0" "192.168.1.1" "202.101.202.68" "202.101.224.69"
goto checkConfigWifi

:applyDhcp
set INTERFACE_NAME=%1
netsh interface ipv4 set address name=%INTERFACE_NAME% source=dhcp
netsh interface ipv4 set dns name=%INTERFACE_NAME% source=dhcp
echo DHCP已启用.
goto :eof

:applyDhcpWithFixedDns
set INTERFACE_NAME=%1
set FIXED_DNS=%2
set SECONDARY_DNS=202.101.202.68
netsh interface ipv4 set address name=%INTERFACE_NAME% source=dhcp
netsh interface ipv4 set dns name=%INTERFACE_NAME% static %FIXED_DNS%
netsh interface ipv4 add dns name=%INTERFACE_NAME% %SECONDARY_DNS% index=2
echo DHCP已启用，并设置了固定的DNS服务器.
goto :eof

:applyIp
set INTERFACE_NAME=%1
set NEW_IP=%2
set SUBNET_MASK=%3
set DEFAULT_GATEWAY=%4
set DNS_SERVER=%5

netsh interface ipv4 set address name=%INTERFACE_NAME% static %NEW_IP% %SUBNET_MASK% %DEFAULT_GATEWAY%
netsh interface ipv4 set dns name=%INTERFACE_NAME% static %DNS_SERVER%
netsh interface ipv4 add dns name=%INTERFACE_NAME% 202.101.202.68 index=2
echo IP配置已更新.
goto :eof

:checkConfigEthernet
echo 显示当前有线网络配置...
netsh interface ip show config name="以太网"
pause
goto menu

:checkConfigWifi
echo 显示当前无线网络配置...
netsh interface ip show config name="WLAN"
pause
goto menu

:flushDns
echo 正在刷新DNS缓存...
ipconfig /flushdns
echo DNS缓存已刷新。
pause
goto menu

:end
echo 程序结束。
pause
exit