当前位置：首页 > article >正文

『功能项目』销毁怪物蛋的Shaders消融特效【17】

article 2024/11/15 11:20:17

本章项目成果展示

我们打开上一篇16主角的信息显示的项目，

本章要做的事情是在怪物消亡时生成一个销毁特效

首先创建一个Unlit Shader

重命名为Dissolve

双击进入脚本后编写脚本：

Shader "Unlit/Dissolve"{
    Properties{
        //物体基础材质纹理
        [Header(Base Texture)]
        [Space(10)]
        [NoScaleOffset]_Albedo("Albedo",2D) = "bump"{}
        //高光
        [NoScaleOffset]_Specular("Specular_Smoothness",2D) = "black"{}
        //法向
        //"bump"{}表示默认 (0.5,0.5,1)紫色纹理
        [NoScaleOffset]_Normal("Normal",2D) = "bump"{}
        //环境光遮蔽
        [NoScaleOffset]_AO("AO",2D) = "white"{}
        //消融属性
        [Header(Dissolve Properties)][Space(10)]
        //控制消融形状的噪声图
        _Noise("Dissolve Noise",2D) = "white"{}
        //控制消融进度
        _Dissolve("Dissolve",Range(0,1))=0
        //控制边缘的颜色
        [NoScaleOffset]_Gradient("Edge Gradient",2D) = "black"{}
        //控制边缘的范围
        _Range("Edge Range",Range(2,100))=6
        //控制边缘的亮度
        _Brightness("Brightness",Range(0,10))=1
    }
    SubShader{
        Tags{
            //开启透明测试 丢弃给定数值的像素 下面两个声明一般是一起的
            //用于透明剪裁的效果
            "RenderType"="TransparentCutout"
            "Queue"="AlphaTest"
        }
        CGPROGRAM
        //表示使用表面着色器 光照模型为StandardSpecular
        //addshadow表示不透明的部分也能产生正确的投影
        //fullforwardshadows表示物体支持所有类型灯光的阴影，默认状态下支支持平行光
        #pragma surface surf StandardSpecular addshadow fullforwardshadows
        
        //Input结构体
        //'uv_'+'纹理的名称' 用于获取对应纹理的第一套纹理坐标
        //如果是uv2则时获取第二套 以此类推
        struct Input {
            float2 uv_Albedo;
            float2 uv_Noise;
        };
        //上面的Properties中声明的知识为了在编辑器中显示，可有可无
        sampler2D _Albedo;
        sampler2D _Specular;
        sampler2D _Normal;
        sampler2D _AO;

        sampler2D _Noise;
        fixed _Dissolve;
        sampler2D _Gradient;
        float _Range;
        float _Brightness;

        //Input时上面声明的Input结构体 
        //SurfaceOutputStandardSpecular表示自带的高光工作流结构体
        void surf(Input IN, inout SurfaceOutputStandardSpecular o) {
            //根据噪声图剪辑
            //tex2D(纹理，纹理坐标)用于获取纹理的颜色信息
            //.r表示颜色rgba中的r值(用xyzw也是一样的道理)
            fixed noise = tex2D(_Noise, IN.uv_Noise).r;
            fixed dissolve = _Dissolve * 2 - 1;
            //saturate(x)表示将x的范围截取到(0,1)之间
            fixed mask = saturate(noise - dissolve);
            //clip(x)如果x小于0 则在最终输出中剔除这个像素
            clip(mask - 0.5);

            //边缘燃烧
            fixed texcoord = saturate(mask * _Range - 0.5 * _Range);
            o.Emission = tex2D(_Gradient, fixed2(texcoord, 0.5)) * _Brightness;

            //正常的纹理
            fixed4 c = tex2D(_Albedo, IN.uv_Albedo);
            o.Albedo = c.rgb;

            //高光
            fixed4 specular = tex2D(_Specular, IN.uv_Albedo);
            o.Specular = specular.rgb;
            o.Smoothness = specular.a;

            //发现与环境光遮蔽
            o.Normal = UnpackNormal(tex2D(_Normal, IN.uv_Albedo));
            o.Occlusion = tex2D(_AO, IN.uv_Albedo);
        }
        ENDCG
    }
}

在新建的Shader脚本右键创建一个该Shader的材质Material

将一下资源图片添加至如下

新建脚本：DissolveController

编写脚本：

using UnityEngine;
public class DissolveController : MonoBehaviour{
    //网格渲染组件
    MeshRenderer m_MeshRenderer;
    //测试状态
    bool isTest = false;
    //消融参数
    float dissolve = 0f;
    //消融速度
    float dissolveSpeed = 0.3f;
    void Start(){
        m_MeshRenderer = GetComponent<MeshRenderer>();
        isTest = true;
    }
    void Update(){
        //按下空格执行消融测试
        if (Input.GetKeyDown(KeyCode.Space) && !isTest) {
            isTest = true;
        }
        //通过事件控制材质的消融参数
        if (isTest) {
            dissolve += Time.deltaTime * dissolveSpeed;
            //用SetFloat方法设置材质相应的属性
            m_MeshRenderer.material.SetFloat("_Dissolve", dissolve);
            if (dissolve > 1f) {
                isTest = false;
                dissolve = 0f;
            }
        }
    }
    public void DissolveValue(float value){
        dissolve = value;
        m_MeshRenderer.material.SetFloat("_Dissolve", dissolve);
    }
}

（这里有冗余代码，是为了测试以及让其外部类调用溶解效果，也可以在Start()函数里将isTest改为false，运行项目后按空格Space键即可消融）

新建一个球体调至缩放倍数，重命名为MonsterKingDieEffect，并且挂载新建材质以及控制脚本

放进Prefabs的预制体文件夹中

修改脚本：MonsterKing.cs(当怪物King消亡时调用生成一个消融效果)

运行项目 - 怪物消亡时

本篇做了主角的UI信息显示升级的功能，接下来还需做以下内容：

1.怪物死亡掉落物品

2.掉落物品拾取

3.背包道具的转移与穿戴

4.异步传送转换场景

5.目标点巡航功能

6.坐骑模型的召唤与取消

7.乘坐坐骑

以及开放回合制、坐骑系统、宠物系统、背包系统、神炼系统、商城系统、Boss的目标跟随任务导航系统以及UI播放3D动画效果等等。

具体项目运行效果请关注water1024的b站视频项目演示《破碎纪元》

【Unity回合2.5D】破碎纪元_单机游戏热门视频 (bilibili.com)https://www.bilibili.com/video/BV1rZY4e9Ebs/?spm_id_from=333.999.0.0&vd_source=547091a95b03acfa8e8a9e46ef499cd6