window系统下nginx管理脚本

下载Nginx

nginx官方下载地址
nginx-1.26.2

解压Nginx

编写cmd脚本

@echo off
rem 提供Windows下Nginx的启动，重载，关闭功能
 
echo ==================begin========================
 
cls
 
rem Nginx 所在目录
set NGINX_DIR=%cd%\
color 0a 
TITLE Nginx 管理面板
 
CLS 
 
echo. 
echo. ***** Nginx 管理程序 *****
echo. 
 
:MENU 
 
echo. ***** Nginx 进程列表 ****** 
tasklist /fi "imagename eq nginx.exe"
 
echo. 
::*************************************************************************************************************
echo. ***** Nginx 菜单列表 ****** 
    echo.  [1] 刷新控制台
    echo.  [2] 启动Nginx  
    echo.  [3] 关闭Nginx  
    echo.  [4] 重载Nginx
    echo.  [5] 检测Nginx
    echo.  [6] 查看Nginx
    echo.  [0] 退 出 
echo. 
 
echo.请输入选择的序号:
set /p ID=
    IF "%id%"=="1" GOTO MENU
	IF "%id%"=="2" GOTO start 
    IF "%id%"=="3" GOTO stop
    IF "%id%"=="4" GOTO reloadConf 
    IF "%id%"=="5" GOTO checkConf 
    IF "%id%"=="6" GOTO showVersion 
    IF "%id%"=="0" EXIT
PAUSE
 
rem *************************************************************************************************************
rem 启动
:start 
    call :startNginx
    GOTO MENU
 
rem 停止
:stop 
    call :shutdownNginx
    GOTO MENU
 
rem 检查测试配置文件
:checkConf 
    call :checkConfNginx
    GOTO MENU
 
rem 重新加载Nginx配置文件
:reloadConf 
    call :checkConfNginx
    call :reloadConfNginx
    GOTO MENU
    
rem 显示nginx版本
:showVersion 
    call :showVersionNginx
    GOTO MENU   
    
    
rem *************************************************************************************
rem 底层
rem *************************************************************************************
:shutdownNginx
    echo. 
    echo.关闭Nginx...... 
    taskkill /F /IM nginx.exe > nul
    echo.已关闭所有Nginx进程
    goto :eof
 
:startNginx
    echo. 
    echo.启动Nginx...... 
    IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe-"不存在
        goto :eof
     )
 
    cd "%NGINX_DIR%" 
    start "NginxMgr" nginx.exe
    echo.OK
    goto :eof
 
:checkConfNginx
    echo. 
    echo.检查测试 Nginx 配置文件......
    IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe-"不存在
        goto :eof
     )
 
    cd "%NGINX_DIR%" 
    nginx -t -c conf/nginx.conf
    goto :eof
    
rem 重新加载 nginx 配置文件
:reloadConfNginx
    echo. 
    IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe-"不存在
        goto :eof
     )
 
    cd "%NGINX_DIR%" 
	echo.重新加载 Nginx 配置文件......
    nginx -s reload
    goto :eof
    
rem 显示nginx版本
:showVersionNginx
    echo. 
    IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe-"不存在
        goto :eof
     )
    cd "%NGINX_DIR%" 
	echo.Nginx版本
    nginx -v
    goto :eof

将脚本放到nginx主目录

效果