【Unity3D】LOD Group 多细节层次（CrossFade淡出淡入效果）

新建一个空物体挂载LOD Group脚本 LOD0（球体） LOD1（立方体） LOD2（单面板Quad）

可发现我勾选了Cross Fade并没有渐隐效果，是因为Shader是不透明的，不支持。

经过如下修改后支持Cross Fade 淡出淡入效果（注意3个物体的材质是不一样的，Shader一样）

Fade Transition Width 越小越慢渐变，越大越快开始渐变。
案例的LOD0、1、2的值分别是0.05、0.1、0.3 

使用如下着色器支持透明化且支持Cross Fade模式：即LOD0和LOD1之间 以及 LOD1与LOD2的淡出淡入。

LOD核心代码部分：

LOD_FADE_CROSSFADE变体是由LOG Group选择Cross Fade模式自动设置的。
unity_LODFade.x是传入的渐变透明度，当是负数时说明是淡入物体的透明度值，需要+1操作，负数时是从-1变化到0，+1后就是从0变化到1。
当是正数时，说明是淡出物体的透明度值，直接拿来使用。
unity_LODFade.y是LOD Level
具体参数数值可以打开FrameDebugger调试器看，在淡出淡入时会同时渲染2个LOD物体的。

#pragma multi_compile _ LOD_FADE_CROSSFADE

... ...

float lodFadeAlpha = 1;
#if LOD_FADE_CROSSFADE
	lodFadeAlpha = unity_LODFade.x;
	if(lodFadeAlpha < 0)
		lodFadeAlpha = 1 + lodFadeAlpha;
#endif
return fixed4(ambient + diffuse * atten, lodFadeAlpha * col.a * _Alpha);

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
 
Shader "MilkShader/Nine/AlphaBlendShadow"
{
	Properties
	{
		_MainTex ("MainTexture", 2D) = "while"{}
		_Diffuse ("Diffuse", Color) = (1,1,1,1)		
		_Alpha ("Alpha", Range(0,1))  = 1
	}
	SubShader
	{
		Tags { "RenderType"="Transparent" "IgnoreProjector" = "True" "Queue"="Transparent" }
		//LOD 100
		
		Pass
		{
			Tags
			{
				"LightMode" = "ForwardBase"
			}
			Blend SrcAlpha OneMinusSrcAlpha			
			ZWrite Off
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma multi_compile_fwdbase
			#pragma multi_compile _ LOD_FADE_CROSSFADE
			
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
 
			struct appdata
			{
				float4 vertex : POSITION;			
				float3 normal : NORMAL;
				float2 uv : TEXCOORD0;
			};
 
			struct v2f
			{			
				float2 uv : TEXCOORD0;
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD1;
				float3 worldPos : TEXCOORD2;			
				SHADOW_COORDS(3)
			};
 
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed4 _Diffuse;
			fixed _Alpha;
			
			v2f vert (appdata v)
			{
				v2f o;
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				o.pos = UnityObjectToClipPos(v.vertex);				
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				TRANSFER_SHADOW(o)
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{				
				fixed4 col = tex2D(_MainTex, i.uv);
				fixed3 albeto = col.rgb * _Diffuse.rgb;
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 diffuse = _LightColor0.rgb * albeto * saturate(dot(worldNormal,worldLightDir));
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albeto;
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				float lodFadeAlpha = 1;
				#if LOD_FADE_CROSSFADE				
					lodFadeAlpha = unity_LODFade.x;
					if(lodFadeAlpha < 0)
						lodFadeAlpha = 1 + lodFadeAlpha;
				#endif
				return fixed4(ambient + diffuse * atten, lodFadeAlpha * col.a * _Alpha);
			}
			ENDCG
		}
	}
	//正常使用的是如下，不会生成阴影!
	FallBack "Transparent/VertexLit"
 
	//开启阴影投射(因为VertexLit中有"LightMode" = "ShadowCaster"的Pass生成阴影图
	//FallBack "VertexLit"
}

Speed Tree效果 待研究，是一种Mesh混合处理...